Токовый выход 4–20 мА на XTR111

В данном уроке соберем преобразователь напряжение–ток на микросхеме XTR111. На вход схемы будем подавать управляющее напряжение, а на выходе получать промышленный токовый сигнал приблизительно от 4 мА до 20 мА.

Диапазон 4–20 мА широко используется в промышленной автоматике для передачи аналоговых сигналов от датчиков и измерительных устройств на ПЛК.

Такой сигнал можно использовать, например, с аналоговыми входами контроллеров Siemens или других промышленных контроллеров.

Схема подключения XTR111

Для формирования токового сигнала используем следующую схему:

Разъем J1 используется для подачи входного управляющего напряжения. Разъем J2 — питание схемы. Разъем J3 — токовый выход.

Основным элементом схемы является XTR111AIDGQR. Она преобразует напряжение на входе VIN в выходной ток.

Для работы выходного каскада используется внешний P-канальный MOSFET BSP170P. Транзистор принимает на себя основную часть рассеиваемой мощности.

Как XTR111 задает выходной ток

Основная формула имеет вид:

IOUT = 10 × VIN / RSET

В нашей схеме сопротивление RSET = R6 = 1,65 кОм.

Для получения тока 4 мА:

VIN = IOUT × RSET / 10

VIN = 0,004 × 1650 / 10 = 0,66 В

Верхняя точка диапазона:

IOUT = 10 × 3,3 / 1650 = 0,020 А = 20 мА

Таким образом, при RSET = 1,65 кОм напряжению VIN около 0,66 В соответствует ток 4 мА, а напряжению 3,3 В — примерно 20 мА.

Встроенный источник 3,3 В

В XTR111 имеется собственный регулируемый источник напряжения. В нашей схеме он настроен на 3,3 В резисторами R2 и R3.

VREGF = 3 В × (R2 + R3) / R3

VREGF = 3 × (3,3 + 33) / 33 = 3,3 В

На собранной плате на выводе REGF также было получено около 3,3 В.

Настройка нижней точки 4 мА

Первоначально в схеме был установлен резистор R1 = 40 кОм. При входном напряжении 0 В на VIN было получено около 1,2 В.

IOUT = 10 × 1,2 / 1650 ≈ 7,27 мА

На практике было измерено около 7 мА. Для уменьшения минимального тока сопротивление R1 увеличили.

Результат:
R1 = 100 кОм.
Входное напряжение = 0 В.
Выходной ток = 3,89 мА.

Такой результат практически соответствует требуемой нижней точке 4 мА.

Важно. Окончательную настройку нижней точки лучше выполнять уже на собранной плате по миллиамперметру.

Быстрая проверка XTR111

При нормальной работе напряжения VIN и SET практически одинаковы.

Поэтому ток можно быстро оценить по измеренному VIN:

IOUT = 10 × VIN / 1650

Например:

IOUT = 10 × 0,642 / 1650 ≈ 3,89 мА

Основные выводы XTR111

Вывод Название Назначение
1 VSP Питание микросхемы.
2 IS Управляемый токовый выход.
3 VG Управление затвором внешнего MOSFET.
4 REGS Обратная связь внутреннего стабилизатора.
5 REGF Выход внутреннего стабилизатора.
6 VIN Аналоговый управляющий вход.
7 SET Подключение RSET.
8 EF Флаг ошибки.
9 OD Отключение выходного каскада.
10 GND Общий провод.

Добавляем цифровое управление током 4–20 мА

До этого управляющее напряжение для XTR111 мы задавали непосредственно на входе схемы. Теперь сделаем управление цифровым.

Для этого добавим 12-битный ЦАП MCP4725, который управляется по шине I²C.

Микроконтроллер будет передавать в MCP4725 цифровое значение, а ЦАП преобразует его в аналоговое напряжение. Это напряжение далее поступает на вход преобразователя XTR111 и определяет выходной ток.

Схема питания и ЦАП MCP4725

На вход схемы подается промышленное питание 24 В.

Так как MCP4725 должен питаться от низкого напряжения, в схему добавлен импульсный DC/DC-преобразователь на микросхеме TPS54560.

Он преобразует входные 24 В в напряжение 3,3 В, которое используется для питания MCP4725 и подтяжки линий I²C.

Получаем следующую цепочку:

24 В → TPS54560 → 3,3 В → MCP4725 → аналоговое напряжение → XTR111 → 4–20 мА.

Подключение I²C

В схеме линии SDA и SCL подтянуты резисторами 4,7 кОм к питанию 3,3 В.

Для Arduino Nano используются:

Arduino Nano MCP4725
A4 SDA
A5 SCL
GND GND
Важно. Arduino Nano, плата ЦАП и плата XTR111 должны иметь общий GND. Питание 5 В Arduino Nano не подключаем к линии питания 3,3 В MCP4725.

Адрес MCP4725

В схеме используется MCP4725A1T-E/CH.

Для этого варианта адрес зависит от состояния вывода A0.

A0 I²C адрес
GND 0x62
3,3 В 0x63

В тестовой программе будем автоматически проверять оба варианта.

Вывод A0 не следует оставлять в неопределенном состоянии. Его необходимо соединить либо с GND, либо с 3,3 В.

Проверяем управление с Arduino Nano

Для первого теста используем обычный потенциометр.

Его подключаем следующим образом:

  • один край потенциометра — к 5 В Arduino Nano;
  • второй край — к GND;
  • средний вывод потенциометра — к входу A0 Arduino Nano.

Arduino измеряет напряжение на движке потенциометра встроенным АЦП.

Полученное значение преобразуется из диапазона 0…1023 в диапазон 0…4095 для 12-битного MCP4725.

В результате:

Потенциометр → АЦП Arduino → число 0…1023 → преобразование в 0…4095 → I²C → MCP4725 → 0…3,3 В → XTR111 → изменение выходного тока.

Тестовая программа Arduino Nano

Для работы используется стандартная библиотека Wire.h, поэтому дополнительные библиотеки устанавливать не нужно.

#include <Wire.h>


/*
   Arduino Nano

   Потенциометр:
   A0

   I2C:
   A4 = SDA
   A5 = SCL

   MCP4725A1:
   A0 = 0 -> 0x62
   A0 = 1 -> 0x63
*/


const uint8_t POT_PIN = A0;


uint8_t dacAddress = 0;


/* ==========================================================
   Проверка наличия устройства на I2C
   ========================================================== */

bool i2cDevicePresent(uint8_t address)
{
    Wire.beginTransmission(address);

    return (Wire.endTransmission() == 0);
}


/* ==========================================================
   Поиск MCP4725
   ========================================================== */

bool findDAC()
{
    if (i2cDevicePresent(0x62))
    {
        dacAddress = 0x62;

        return true;
    }


    if (i2cDevicePresent(0x63))
    {
        dacAddress = 0x63;

        return true;
    }


    return false;
}


/* ==========================================================
   Запись значения в MCP4725

   value:
   0 ... 4095
   ========================================================== */

void setDAC(uint16_t value)
{
    value &= 0x0FFF;


    Wire.beginTransmission(dacAddress);


    /*
       Fast Write Mode.

       Первый байт:
       PD1 = 0
       PD0 = 0
       D11...D8
    */

    Wire.write(
        (value >> 8) & 0x0F
    );


    /*
       Второй байт:
       D7...D0
    */

    Wire.write(
        value & 0xFF
    );


    Wire.endTransmission();
}



void setup()
{
    Serial.begin(115200);


    Wire.begin();


    /*
       Для первого теста
       используем стандартные 100 кГц.
    */

    Wire.setClock(100000);


    delay(200);


    Serial.println();

    Serial.println(
        "MCP4725 + XTR111 test"
    );


    if (!findDAC())
    {
        Serial.println(
            "MCP4725 not found!"
        );


        while (1)
        {
            delay(1000);
        }
    }


    Serial.print(
        "MCP4725 address: 0x"
    );

    Serial.println(
        dacAddress,
        HEX
    );


    /*
       При запуске устанавливаем
       минимальное выходное напряжение ЦАП.
    */

    setDAC(0);
}



void loop()
{
    uint32_t adcSum = 0;


    /*
       Небольшое усреднение,
       чтобы значение потенциометра
       меньше дрожало.
    */

    for (uint8_t i = 0; i < 16; i++)
    {
        adcSum += analogRead(POT_PIN);
    }


    uint16_t adcValue =
        adcSum / 16;


    /*
       Arduino ADC:
       0 ... 1023

       MCP4725:
       0 ... 4095
    */

    uint16_t dacValue =
        map(
            adcValue,
            0,
            1023,
            0,
            4095
        );


    setDAC(dacValue);


    /*
       Расчетное напряжение
       на выходе MCP4725.

       VDD MCP4725 = 3.3 V
    */

    float dacVoltage =
        3.3f *
        ((float)dacValue / 4095.0f);


    /*
       Ориентировочное значение тока.

       Реальный ток обязательно
       проверяем миллиамперметром
       после XTR111.
    */

    float currentExpected =
        4.0f +
        16.0f *
        ((float)dacValue / 4095.0f);


    Serial.print(
        "ADC = "
    );

    Serial.print(
        adcValue
    );


    Serial.print(
        "   DAC = "
    );

    Serial.print(
        dacValue
    );


    Serial.print(
        "   Vout = "
    );

    Serial.print(
        dacVoltage,
        3
    );

    Serial.print(
        " V"
    );


    Serial.print(
        "   I ~= "
    );

    Serial.print(
        currentExpected,
        2
    );

    Serial.println(
        " mA"
    );


    delay(100);
}

Как работает программа

1. Считываем потенциометр

adcValue = analogRead(A0);

Arduino Nano имеет 10-битный АЦП, поэтому результат находится в диапазоне от 0 до 1023.

2. Преобразуем значение для ЦАП

dacValue = map(
    adcValue,
    0,
    1023,
    0,
    4095
);

MCP4725 является 12-битным ЦАП, поэтому используется диапазон от 0 до 4095.

3. Передаем значение по I²C

Wire.beginTransmission(dacAddress);

Wire.write(
    (dacValue >> 8) & 0x0F
);

Wire.write(
    dacValue & 0xFF
);

Wire.endTransmission();

После получения данных MCP4725 изменяет аналоговое напряжение на выходе VOUT.

4. Изменяем ток 4–20 мА

Напряжение с выхода MCP4725 подаем на управляющий вход платы XTR111.

При вращении потенциометра значение АЦП Arduino изменяется, вслед за ним изменяется код MCP4725, напряжение на выходе ЦАП и ток на выходе XTR111.

Значение тока, которое выводится программой в Serial Monitor, пока является только расчетным. Во время первого запуска реальный ток обязательно измеряем миллиамперметром. По результатам измерений скорректируем коэффициенты и при необходимости ограничим программный диапазон ЦАП.

Порядок первого запуска

1. Пока не подключаем XTR111 и проверяем только DC/DC-преобразователь.

На выходе питания MCP4725 должно быть около 3,3 В.

2. Подключаем Arduino Nano к SDA и SCL.

В Serial Monitor должен определиться MCP4725 по адресу 0x62 или 0x63.

3. Вращаем потенциометр и измеряем выход VOUT MCP4725.

Напряжение должно плавно изменяться приблизительно от 0 В до 3,3 В.

4. Соединяем VOUT MCP4725 со входом платы XTR111 и объединяем земли.

5. Включаем миллиамперметр в токовую петлю.

6. Медленно вращаем потенциометр от минимального положения к максимальному и записываем реальные значения:

Положение Выход ЦАП Ток XTR111
Минимум около 0 В проверяем
25% около 0,825 В проверяем
50% около 1,65 В проверяем
75% около 2,475 В проверяем
Максимум около 3,3 В проверяем

Что будем проверять после сборки

На первом этапе нам важно проверить три отдельных узла:

  • стабильные 3,3 В после TPS54560;
  • работу MCP4725 по I²C и диапазон VOUT 0…3,3 В;
  • соответствие выходного тока XTR111 напряжению с ЦАП.

После измерений уже можно будет скорректировать программу, чтобы крайние положения потенциометра точно соответствовали 4,00 мА и 20,00 мА.